Author: ivan: обзор

Ну допустим, я показал ему текст некоторой программы:

REPORT y_bc001_text_search.

TABLES: tadir.

SELECT-OPTIONS: s_devc FOR tadir-devclass DEFAULT 'Z*' OPTION CP.
SELECT-OPTIONS: s_objec FOR tadir-object.
SELECT-OPTIONS: s_objnm FOR tadir-obj_name DEFAULT 'Z*' OPTION CP.
PARAMETERS: p_text TYPE string.

START-OF-SELECTION.

  SELECT
    tadir~pgmid,
    tadir~object,
    tadir~obj_name,
    trdir~subc,
    tadir~devclass
    FROM tadir
    LEFT OUTER JOIN trdir ON tadir~object = 'PROG' AND tadir~obj_name = trdir~name
    INTO TABLE @DATA(lt_objects)
   WHERE tadir~devclass IN @s_devc
     AND tadir~object IN @s_objec
     AND tadir~obj_name IN @s_objnm
      AND ( tadir~object = 'PROG' OR tadir~object = 'FUGR' OR tadir~object = 'CLAS' ).

  LOOP AT lt_objects ASSIGNING FIELD-SYMBOL(<object>).
    IF <object>-object = 'PROG'  AND ( <object>-subc = '1' OR <object>-subc = 'M' ).

      DATA: lt_tpool TYPE STANDARD TABLE OF textpool WITH DEFAULT KEY.
      CALL FUNCTION 'RS_TEXTPOOL_READ'
        EXPORTING
          objectname           = <object>-obj_name
          action               = 'READ'
*         AUTHORITY_CHECK      = ' '
          language             = sy-langu
        TABLES
          tpool                = lt_tpool
        EXCEPTIONS
          object_not_found     = 1
          permission_failure   = 2
          invalid_program_type = 3
          error_occured        = 4
          action_cancelled     = 5
          OTHERS               = 6.
      IF sy-subrc <> 0.
* Implement suitable error handling here
      ENDIF.

      LOOP AT lt_tpool ASSIGNING FIELD-SYMBOL(<tpool>).
        IF <tpool>-id = 'I' AND <tpool>-entry CP p_text.
          WRITE: <object>-obj_name, <tpool>-key, <tpool>-entry.
        ENDIF.
      ENDLOOP.
    ELSEIF <object>-object = 'FUGR'.

      DATA: lv_fugr TYPE rs38m-programm.
      lv_fugr = 'SAPL' && <object>-obj_name.

      CALL FUNCTION 'RS_TEXTPOOL_READ'
        EXPORTING
          objectname           = lv_fugr
          action               = 'READ'
*         AUTHORITY_CHECK      = ' '
          language             = sy-langu
        TABLES
          tpool                = lt_tpool
        EXCEPTIONS
          object_not_found     = 1
          permission_failure   = 2
          invalid_program_type = 3
          error_occured        = 4
          action_cancelled     = 5
          OTHERS               = 6.
      IF sy-subrc <> 0.
* Implement suitable error handling here
      ENDIF.

      LOOP AT lt_tpool ASSIGNING <tpool>.
        IF <tpool>-id = 'I' AND <tpool>-entry CP p_text.
          WRITE: <object>-obj_name, <tpool>-key, <tpool>-entry.
        ENDIF.
      ENDLOOP.

    ELSEIF <object>-object = 'CLAS'.

      DATA: lv_clas TYPE rs38m-programm.
      lv_clas = <object>-obj_name.

      DATA(lv_eq_count) = 30 - strlen( lv_clas ).
      DO lv_eq_count TIMES.
        lv_clas = lv_clas && '='.
      ENDDO.
      lv_clas = lv_clas && 'CP'.

      CALL FUNCTION 'RS_TEXTPOOL_READ'
        EXPORTING
          objectname           = lv_clas
          action               = 'READ'
*         AUTHORITY_CHECK      = ' '
          language             = sy-langu
        TABLES
          tpool                = lt_tpool
        EXCEPTIONS
          object_not_found     = 1
          permission_failure   = 2
          invalid_program_type = 3
          error_occured        = 4
          action_cancelled     = 5
          OTHERS               = 6.
      IF sy-subrc <> 0.
* Implement suitable error handling here
      ENDIF.

      LOOP AT lt_tpool ASSIGNING <tpool>.
        IF <tpool>-id = 'I' AND <tpool>-entry CP p_text.
          WRITE: <object>-obj_name, <tpool>-key, <tpool>-entry.
        ENDIF.
      ENDLOOP.
    ENDIF.

  ENDLOOP.

END-OF-SELECTION.

  WRITE: / 'Search completed:', p_text.

Так вот, сервис может пояснить за код, лучше чем я:

(more…)

Есть в ABAP кое-какие языковые конструкции, отсутствующие в топовых языках, по крайней мере на базовом уровне, например MOVE-CORRESPONDING.

VARYING – это одна из таких конструкций. Я изредка использовал её в базовом варианте:

DATA: BEGIN OF ls_varstr,
        cod01 TYPE char20,
        cod02 TYPE char20,
        cod03 TYPE char20,
        cod04 TYPE char20,
      END OF ls_varstr.

ls_varstr = VALUE #(
  cod01 = '001'
  cod02 = '002'
  cod03 = '003'
  cod04 = '004'
).

DATA: lv_code  TYPE char20.

DO 4 TIMES VARYING lv_code FROM ls_varstr-cod01  NEXT ls_varstr-cod02.

  WRITE: / lv_code.

ENDDO.

Результат предсказуем:

Но как иногда оказывается, у этой конструкции есть две дополнительных глубины.

Во-первых, можно крутить два поля одновременно:

DATA: BEGIN OF ls_varstr,
        cod01 TYPE char20,
        val01 TYPE char100,
        cod02 TYPE char20,
        val02 TYPE char100,
        cod03 TYPE char20,
        val03 TYPE char100,
        cod04 TYPE char20,
        val04 TYPE char100,
      END OF ls_varstr.

ls_varstr = VALUE #(
  cod01 = '001' val01 = 'First'
  cod02 = '002' val02 = 'Second'
  cod03 = '003' val03 = 'Third'
  cod04 = '004' val04 = 'Fofth'
).

DATA: lv_code  TYPE char20.
DATA: lv_value TYPE char100.

DO 4 TIMES
   VARYING lv_code FROM ls_varstr-cod01  NEXT ls_varstr-cod02
   VARYING lv_value FROM ls_varstr-val01  NEXT ls_varstr-val02.

  WRITE: / lv_code, '=', lv_value .

ENDDO.

И оказывается так тоже можно, результат не удивит:

А во-вторых, поля в последовательности могут называться как угодно.

Мне раньше казалось, что нумерация в поле очень важна: VAL01, VAL02. Магия! А вот нет. Так тоже можно:

DATA: BEGIN OF ls_varstr,
        first         TYPE char20,
        second        TYPE char20,
        i-do-not-know TYPE char20,
        wtf           TYPE char20,
      END OF ls_varstr.

ls_varstr = VALUE #(
  first         = '001'
  second        = '002'
  i-do-not-know = '003'
  wtf           = '004'
).

DATA: lv_code  TYPE char20.

DO 4 TIMES VARYING lv_code FROM ls_varstr-first  NEXT ls_varstr-second.

  WRITE: / lv_code.

ENDDO.

Если чуть подумать, то станет всё понятнее, как оно было заложено и почему. Могу проиллюстрировать на менее интуитивно понятном примере:

DATA: BEGIN OF ls_varstr,
        cod01     TYPE char20,
        val01     TYPE char100,
        cod02     TYPE char20,
        val02     TYPE char100,
        cod03     TYPE char20,
        val03     TYPE char100,
        cod04     TYPE char20,
        val04     TYPE char100,

        other     TYPE text60,
        fields    TYPE text60,
      END OF ls_varstr.

ls_varstr = VALUE #(
  cod01 = '001' val01 = 'First'
  cod02 = '002' val02 = 'Second'
  cod03 = '003' val03 = 'Third'
  cod04 = '004' val04 = 'Fofth'

  other     = 'Other~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
  fields    = 'Fields~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
).

DATA: lv_code  TYPE char20.
DATA: lv_value TYPE char100.

DO 5 TIMES
   VARYING lv_code FROM ls_varstr-cod01  NEXT ls_varstr-cod02
   VARYING lv_value FROM ls_varstr-val01  NEXT ls_varstr-val02.

  WRITE: / lv_code, '=', lv_value .

ENDDO.

Обратите внимание на DO 5 TIMES. Ха-ха? Знаете что произойдёт?

(more…)